***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May. 29, 2025                                                        *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ54601A-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs     s1    s2    205u TC=3m
Rg     g1    g2    2.70
M1     d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS PMOS ( KP=170  VTO=-1.94  VMAX=1e5  ETA=0  NFS=3.000e11  LEVEL=3  GAMMA=1 )
Rd     d1    d2    9.515e-3 TC=5.700e-3,7.000e-6
Dbd    d2    s2    Dbt
.MODEL      Dbt    D(BV=66 TBV1=5.918e-4 TBV2=-2.850e-7  CJO=1.027e-9   M=6.023e-1   VJ=6.881e-1)
Dbody  21    s2    DBODY
.MODEL DBODY  D(IS=8.505e-11   N=1.085  RS=4.000e-5  EG=1.07  TT=30n  IKF=2.555  TIKF=9.500e-3  TRS2=1.500e-4)
Rdiode d1    21    8.580e-4  TC=1.800e-3,-5.000e-6
.MODEL   sw    PMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a     a    sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   7.187e-10
.MODEL    DGD    D(CJO=7.187e-10 M=2.758e-1  VJ=3.905e-1)
Rpar      b    d2   10Meg
Dgd       d2   a   DGD
Rpar2     d2   a    10Meg
Cgs       g2   s2  7.494e-9
.ENDS PJQ54601A-AU
*$
